Open Source Projects Europe

recoll.pro.in    92 lines (74 with data), 2.2 kB

TEMPLATE        = app
LANGUAGE        = C++

CONFIG  += qt warn_on thread release 

HEADERS += \
        ../qtgui/advsearch_w.h \
        ../qtgui/confgui/confgui.h \
        ../qtgui/confgui/confguiindex.h \
        ../qtgui/preview_w.h \
        ../qtgui/rclhelp.h \
        ../qtgui/rclmain_w.h \
        ../qtgui/reslist.h \
        ../qtgui/searchclause_w.h \
        ../qtgui/sort_w.h \
        ../qtgui/spell_w.h \
        ../qtgui/ssearch_w.h \
        ../qtgui/uiprefs_w.h \
        ../qtgui/viewaction_w.h \


SOURCES += \
        ../qtgui/advsearch_w.cpp \
        ../qtgui/confgui/confgui.cpp \
        ../qtgui/confgui/confguiindex.cpp \
        ../qtgui/guiutils.cpp \
        ../qtgui/idxthread.cpp \
        ../qtgui/main.cpp \
        ../qtgui/preview_w.cpp \
        ../qtgui/rclhelp.cpp \
        ../qtgui/rclmain_w.cpp \
        ../qtgui/reslist.cpp \
        ../qtgui/searchclause_w.cpp \
        ../qtgui/sort_w.cpp \
        ../qtgui/spell_w.cpp \
        ../qtgui/ssearch_w.cpp \
        ../qtgui/uiprefs_w.cpp \
        ../qtgui/viewaction_w.cpp \



FORMS   = \
        advsearch.ui \
        preview.ui \
        rclmain.ui \
	sort.ui \
	spell.ui \
        ssearchb.ui \
        uiprefs.ui \
        viewaction.ui \


RESOURCES = recoll.qrc

unix {
  UI_DIR = .ui
  MOC_DIR = .moc
  OBJECTS_DIR = .obj

  LIBS += ../lib/librcl.a \
       $(BSTATIC) @LIBXAPIAN@ $(LIBXAPIANSTATICEXTRA) @LIBICONV@ $(BDYNAMIC) \
           -lz

  INCLUDEPATH += ../common ../index ../internfile ../query ../unac \
              ../utils ../aspell ../rcldb ../qt4gui/.ui \
              ../qtgui ../../qtgui \
              ../qtgui/confgui ../../qtgui/confgui

  POST_TARGETDEPS = ../lib/librcl.a
}

UNAME = $$system(uname -s)
contains( UNAME, [lL]inux ) {
          LIBS -= -liconv 
	  LIBS += -ldl -lX11
}
contains( UNAME, SunOS ) {
          LIBS += -ldl
}

TRANSLATIONS = \
	     ../qtgui/i18n/recoll_de.ts \
             ../qtgui/i18n/recoll_fr.ts \
             ../qtgui/i18n/recoll_it.ts \
             ../qtgui/i18n/recoll_ru.ts \
             ../qtgui/i18n/recoll_tr.ts \
             ../qtgui/i18n/recoll_uk.ts \
             ../qtgui/i18n/recoll_xx.ts \


QT += qt3support