TEMPLATE = app
LANGUAGE = C++
QT += script webkit network
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets webkitwidgets
#QT += script widgets network webenginewidgets
# VERSION is ^egrepped and must stay in the first column
VERSION = 1.1.0
QMAKE_CXXFLAGS += -DUPPLAY_VERSION=\\\"$$VERSION\\\"
QMAKE_CXXFLAGS += -std=c++0x
#QMAKE_CXXFLAGS += -DUSING_WEBENGINE
buildtype = release
CONFIG += qt warn_on thread $$buildtype
# DEFINES += UPPLAY_HORIZONTAL_LAYOUT
HEADERS += \
GUI/widgets/directslider.h \
GUI/mainw/mainw.h \
GUI/mainw/trayicon.h \
GUI/playerwidget/playerhwidget.h \
GUI/playerwidget/playervwidget.h \
GUI/mdatawidget/mdatawidget.h \
GUI/mdatawidget/mdatawidgetif.h \
GUI/volumewidget/volumewidget.h \
GUI/volumewidget/volumewidgetif.h \
GUI/volumewidget/soundslider.h \
GUI/playctlwidget/playctlwidget.h \
GUI/playctlwidget/playctlwidgetif.h \
GUI/progresswidget/progresswidget.h \
GUI/progresswidget/progresswidgetif.h \
GUI/playlist/GUI_Playlist.h \
GUI/playlist/delegate/PlaylistItemDelegate.h \
GUI/playlist/delegate/PlaylistItemDelegateInterface.h \
GUI/playlist/entry/GUI_PlaylistEntry.h \
GUI/playlist/entry/GUI_PlaylistEntryBig.h \
GUI/playlist/entry/GUI_PlaylistEntrySmall.h \
GUI/playlist/model/PlaylistItemModel.h \
GUI/playlist/view/ContextMenu.h \
GUI/playlist/view/PlaylistView.h \
GUI/prefs/confgui.h \
GUI/prefs/prefs.h \
GUI/prefs/sortprefs.h \
GUI/renderchoose/renderchoose.h \
HelperStructs/CSettingsStorage.h \
HelperStructs/Helper.h \
HelperStructs/PlaylistMode.h \
HelperStructs/Style.h \
application.h \
dirbrowser/dirbrowser.h \
dirbrowser/cdbrowser.h \
dirbrowser/rreaper.h \
dirbrowser/randplayer.h \
playlist/Playlist.h \
playlist/PlaylistAVT.h \
playlist/PlaylistOH.h \
upadapt/avtadapt.h \
upadapt/ohpladapt.h \
upqo/avtransport_qo.h \
upqo/cdirectory_qo.h \
upqo/ohplaylist_qo.h \
upqo/ohtime_qo.h \
upqo/ohvolume_qo.h \
upqo/renderingcontrol_qo.h
SOURCES += \
GUI/widgets/directslider.cpp \
GUI/mainw/mainw.cpp \
GUI/mainw/mw_connections.cpp \
GUI/mainw/mw_controls.cpp \
GUI/mainw/mw_cover.cpp \
GUI/mainw/mw_menubar.cpp \
GUI/mainw/trayicon.cpp \
GUI/playerwidget/playerwidget.cpp \
GUI/mdatawidget/mdatawidget.cpp \
GUI/volumewidget/volumewidget.cpp \
GUI/volumewidget/soundslider.cpp \
GUI/playctlwidget/playctlwidget.cpp \
GUI/progresswidget/progresswidget.cpp \
GUI/playlist/GUI_Playlist.cpp \
GUI/playlist/delegate/PlaylistItemDelegate.cpp \
GUI/playlist/entry/GUI_PlaylistEntryBig.cpp \
GUI/playlist/entry/GUI_PlaylistEntrySmall.cpp \
GUI/playlist/model/PlaylistItemModel.cpp \
GUI/playlist/view/ContextMenu.cpp \
GUI/playlist/view/PlaylistView.cpp \
GUI/prefs/confgui.cpp \
GUI/prefs/prefs.cpp \
GUI/prefs/sortprefs.cpp \
HelperStructs/CSettingsStorage.cpp \
HelperStructs/Helper.cpp \
HelperStructs/Style.cpp \
application.cpp \
dirbrowser/dirbrowser.cpp \
dirbrowser/cdbrowser.cpp \
dirbrowser/rreaper.cpp \
dirbrowser/randplayer.cpp \
playlist/Playlist.cpp \
playlist/PlaylistAVT.cpp \
playlist/PlaylistOH.cpp \
upadapt/upputils.cpp \
upplay.cpp
FORMS = \
GUI/mainw/mainw.ui \
GUI/mainw/mainhw.ui \
GUI/playerwidget/playerhwidget.ui \
GUI/playerwidget/playervwidget.ui \
GUI/playctlwidget/playctlwidget.ui \
GUI/progresswidget/progresswidget.ui \
dirbrowser/dirbrowser.ui \
GUI/playlist/GUI_Playlist.ui \
GUI/playlist/entry/GUI_PlaylistEntryBig.ui \
GUI/playlist/entry/GUI_PlaylistEntrySmall.ui \
GUI/prefs/sortprefs.ui \
GUI/renderchoose/renderchoose.ui
unix {
UI_DIR = .ui
MOC_DIR = .moc
OBJECTS_DIR = .obj
LIBS += -lupnpp
isEmpty(PREFIX) {
PREFIX = /usr
}
message("Prefix is $$PREFIX")
DEFINES += PREFIX=\\\"$$PREFIX\\\"
# Installation stuff
target.path = "$$PREFIX/bin"
bdata.files = dirbrowser/cdbrowser.css dirbrowser/dark.css \
dirbrowser/standard.css dirbrowser/containerscript.js
bdata.path = $$PREFIX/share/upplay/cdbrowser
gdata.files = GUI/standard.css GUI/dark.css
gdata.path = $$PREFIX/share/upplay/
desktop.files += upplay.desktop
desktop.path = $$PREFIX/share/applications/
icona.files = GUI/icons/upplay.png
icona.path = $$PREFIX/share/icons/hicolor/48x48/apps/
iconb.files = GUI/icons/upplay.png
iconb.path = $$PREFIX/share/pixmaps/
iconc.files = GUI/icons/*.png
iconc.path = $$PREFIX/share/upplay/icons
icond.files = GUI/icons/*.png GUI/icons/dark/*.png
icond.path = $$PREFIX/share/upplay/icons/dark
INSTALLS += target bdata desktop gdata icona iconb iconc icond
}
windows {
contains(QMAKE_CC, gcc){
# MingW
QMAKE_CXXFLAGS += -std=c++11 -Wno-unused-parameter
}
contains(QMAKE_CC, cl){
# Visual Studio
}
DEFINES += WIN32
DEFINES -= UNICODE
DEFINES -= _UNICODE
DEFINES += _MBCS
DEFINES += PSAPI_VERSION=1
INCLUDEPATH += c:/users/bill/documents/upnp/libupnpp
INCLUDEPATH += c:/users/bill/documents/upnp/pupnp/include
LIBS += -L../libupnpp/windows/build-libupnpp-Desktop_Qt_5_5_0_MinGW_32bit-$$buildtype/$$buildtype -lupnpp
LIBS += c:/users/bill/documents/upnp/expat-2.1.0/.libs/libexpat.a
LIBS += c:/users/bill/documents/upnp/curl-7.43.0/lib/libcurl.a
LIBS += c:/users/bill/documents/upnp/pupnp/upnp/.libs/libupnp.a
LIBS += c:/users/bill/documents/upnp/pupnp/ixml/.libs/libixml.a
LIBS += c:/users/bill/documents/upnp/pupnp/threadutil/.libs/libthreadutil.a
LIBS += -liphlpapi
LIBS += -lwldap32
LIBS += -lws2_32
LIBS += -lshlwapi
}